35c5aee584
Resolves #290 **Build** New commands: - `gen-doc-tests` - only regenerates tests if stale, use `clean` command to force regen - `run-doc-tests` - calls gen-doc-tests then runs tests, accepts the same parameters as run-tests. Can specify `:platform` - `:cljs` - run tests under ClojureScript - otherwise Clojure where we can specify one of: `:1.9` `:1.10` `:master` I'm not sure if my use of the `:platform` parameter jives with your `:aliases` parameter used for `run-tests`. Can adjust if you like. Example usages: ```shell clojure -T:build gen-doc-tests clojure -T:build run-doc-tests :platform :cljs clojure -T:build run-doc-tests clojure -T:build run-doc-tests :platform :1.10 ``` The `ci` command has been updated to generate and run doc tests for same platforms as unit tests. **Articles** In addition to `README.md`, now testing doc blocks in all articles under `doc` dir excepting `doc/operator-reference.md` which does not have any runnable code blocks. **Skipped** Any code block that is intentionally not runnable has been marked to be skipped via: `<!-- :test-doc-blocks/skip -->`. **Consistency** I noticed that some code blocks use REPL syntax: ```Clojure user=> (+ 1 2 3) 6 ``` and others use editor syntax: ```Clojure (+ 1 2 3) ;;=> 6 ``` some places also omit the comment for editor style: ```Clojure (+ 1 2 3) => 6 ``` All of this is just fine with test-doc-blocks. I left the inconsistency as is, but can make a pass for consistency upon request. **HoneySQL state** I noticed a code block that set the sql dialect was affecting other tests. I simply restored the dialect to the default at the end of the code block. **Un-tweaked output** Some code blocks had string output hand-tweaked for readability. These have been adjusted to instead use `sql/format`'s `:pretty` option. In some cases the output is not as readable as the hand-tweaked version. I humbly suggest that perhaps `:pretty` output could perhaps be improved (instead of having test-doc-blocks somehow adapt). **Corrections** There were very few code blocks that required fixing due to incorrect output/code. Please review the diffs carefully to make sure all is as expected. **refer-clojure :excludes** Not currently supported for test-doc-blocks, not a real issue for Clojure, we'll see warnings under Clojure, but that's probably ok. But I might actually need it for ClojureScript. I was finding that `for` did not get overridden by our helper `:refer` in CloureScript. Will add proper support to test-doc-blocks but in the short-term, will use `h/for`. **ns requires adjustments** Any specific case of `(ns my-ns (require [my-require :as a]))` is now the REPL friendly `(require '[my-require :as a])` Any missing required `requires` were added. The HoneySQL docs seem to encourage the use of referred vars for helpers. Although this has the con of overlaps with Clojure core vars, it is also convenient for Clojure when using `:refer :all`. **ClojureScript :refer** ClojureScript does not support `:refer :all` and each var must be specified in place of `:all`. I have adjusted examples accordingly to work with both Clojure and ClojureScript.
125 lines
4.3 KiB
Clojure
125 lines
4.3 KiB
Clojure
(ns build
|
|
"HoneySQL's build script.
|
|
|
|
clojure -T:build run-tests
|
|
clojure -T:build run-tests :aliases '[:master]'
|
|
|
|
clojure -T:build ci
|
|
|
|
For more information, run:
|
|
|
|
clojure -A:deps -T:build help/doc"
|
|
(:require [babashka.fs :as fs]
|
|
[clojure.tools.build.api :as b]
|
|
[clojure.tools.deps.alpha :as t]
|
|
[deps-deploy.deps-deploy :as dd]
|
|
[lread.test-doc-blocks :as tdb]))
|
|
|
|
(def lib 'com.github.seancorfield/honeysql)
|
|
(def version (format "2.0.%s" (b/git-count-revs nil)))
|
|
(def class-dir "target/classes")
|
|
(def basis (b/create-basis {:project "deps.edn"}))
|
|
(def jar-file (format "target/%s-%s.jar" (name lib) version))
|
|
|
|
(defn clean "Remove the target folder." [_]
|
|
(println "\nCleaning target...")
|
|
(b/delete {:path "target"}))
|
|
|
|
(defn jar "Build the library JAR file." [_]
|
|
(println "\nWriting pom.xml...")
|
|
(b/write-pom {:class-dir class-dir
|
|
:lib lib
|
|
:version version
|
|
:scm {:tag (str "v" version)}
|
|
:basis basis
|
|
:src-dirs ["src"]})
|
|
(println "Copying src...")
|
|
(b/copy-dir {:src-dirs ["src"]
|
|
:target-dir class-dir})
|
|
(println (str "Building jar " jar-file "..."))
|
|
(b/jar {:class-dir class-dir
|
|
:jar-file jar-file}))
|
|
|
|
(defn- run-task
|
|
[aliases]
|
|
(println "\nRunning task for:" aliases)
|
|
(let [basis (b/create-basis {:aliases aliases})
|
|
combined (t/combine-aliases basis aliases)
|
|
cmds (b/java-command {:basis basis
|
|
:java-opts (:jvm-opts combined)
|
|
:main 'clojure.main
|
|
:main-args (:main-opts combined)})
|
|
{:keys [exit]} (b/process cmds)]
|
|
(when-not (zero? exit)
|
|
(throw (ex-info (str "Task failed for: " aliases) {})))))
|
|
|
|
(defn gen-doc-tests "Generate tests from doc code blocks" [opts]
|
|
(let [docs ["README.md"
|
|
"doc/clause-reference.md"
|
|
"doc/differences-from-1-x.md"
|
|
"doc/extending-honeysql.md"
|
|
"doc/general-reference.md"
|
|
"doc/getting-started.md"
|
|
"doc/postgresql.md"
|
|
"doc/special-syntax.md"]
|
|
updated-docs (fs/modified-since "target/test-doc-blocks" (conj docs "build.clj" "deps.edn"))]
|
|
(if (seq updated-docs)
|
|
(do
|
|
(println "gen-doc-tests: Regenerating: found newer:" (mapv str updated-docs))
|
|
(tdb/gen-tests {:docs docs}))
|
|
(println "gen-doc-tests: Tests already generated")))
|
|
opts)
|
|
|
|
(defn eastwood "Run Eastwood." [opts] (run-task [:eastwood]) opts)
|
|
|
|
(defn run-tests
|
|
"Run regular tests.
|
|
|
|
Optionally specify :aliases:
|
|
[:1.9] -- test against Clojure 1.9 (the default)
|
|
[:1.10] -- test against Clojure 1.10.3
|
|
[:master] -- test against Clojure 1.11 master snapshot
|
|
[:cljs] -- test against ClojureScript"
|
|
[{:keys [aliases] :as opts}]
|
|
(run-task (into [:test] aliases))
|
|
opts)
|
|
|
|
(defn run-doc-tests
|
|
"Run generated doc tests.
|
|
|
|
Optionally specify :platform:
|
|
:1.9 -- test against Clojure 1.9 (the default)
|
|
:1.10 -- test against Clojure 1.10.3
|
|
:master -- test against Clojure 1.11 master snapshot
|
|
:cljs -- test against ClojureScript"
|
|
[{:keys [platform] :or {platform :1.9} :as opts}]
|
|
(gen-doc-tests opts)
|
|
(let [aliases (case platform
|
|
:cljs [platform :test-doc :test-doc-cljs]
|
|
[platform :runner :test-doc :test-doc-clj])]
|
|
(run-task aliases))
|
|
opts)
|
|
|
|
(defn ci "Run the CI pipeline of tests (and build the JAR)." [opts]
|
|
(-> opts
|
|
(clean)
|
|
(as-> opts
|
|
(reduce (fn [opts platform]
|
|
(run-doc-tests (assoc opts :platform platform)))
|
|
opts
|
|
[:cljs :1.9 :1.10 :master]))
|
|
(eastwood)
|
|
(as-> opts
|
|
(reduce (fn [opts alias]
|
|
(run-tests (assoc opts :aliases (cond-> [alias]
|
|
(not= :cljs alias)
|
|
(conj :runner)))))
|
|
opts
|
|
[:cljs :1.9 :1.10 :master]))
|
|
(clean)
|
|
(jar)))
|
|
|
|
(defn deploy "Deploy the JAR to Clojars." [opts]
|
|
(dd/deploy (merge {:installer :remote :artifact jar-file
|
|
:pom-file (b/pom-path {:lib lib :class-dir class-dir})}
|
|
opts)))
|